bitteschön…

README (wichtig)
in die beiden properties in Admin Credentials müssen anstelle von user und pass die Admin-Userdaten eingeben, dann funktioniert auch das Kopieren aus der lokalen Library.

Der Rechner muss vom Ziel-System (neues System) gebootet sein!
Das script muss als Programm abgespeichert werde. Ort ist allerdings egal.
Ziehe das das SciptProgramm-Icon in ein offenes Finder-Fenster direkt links vom Suchfeld.
Beim ersten Start wird das Quell-Laufwerk (altes System) abgefragt. Die Einstellung ist permanent.
Wenn du die Einstellung ändern willst muss du das script neu kompilieren und abspeichern.

Alles, was kopiert wird, überschreibt eventuell vorhandene Dateien auf dem neuen System.
Es gibt keine Abfrage!

Show Plain Text

(************ Admin Credentials ****************)
 
property _username : "user"
property _password : "pass"
 
(****************************************)
 
property sourceVolume : missing value
 
on reopen
  getSource()
end reopen
 
on run
  if sourceVolume is missing value then getSource()
  activate application "SystemUIServer"
  tell application "Finder"
    activate
    set sel to selection
  end tell
  repeat with i in sel
    set source to POSIX path of (i as alias)
    if source begins with sourceVolume then
      set destination to text ((count sourceVolume) + 1) thru -1 of source
      do shell script "cp -pR " & quoted form of source & space & quoted form of destination user name _username password _password with administrator privileges
    end if
  end repeat
end run
 
on getSource()
  tell application "System Events"
    set startupDisk to name of startup disk
    set volumeNames to name of disks whose name is not startupDisk and format is not NFS format
  end tell
  set sourceDisk to choose from list volumeNames with prompt "Quell-Volume auswählen"
  if sourceDisk is false then return
  set sourceVolume to "/Volumes/" & item 1 of sourceDisk
end getSource